Barevna cisla stranek v obsahu a rejstriku, coby odkazy.

[Jirka Kosek]

Luboš Fík wrote:
> 1. Nevite nahodou, jak obarvit, treba na modro, cisla stranek v obsahu.
> Aby bylo videt ze jde o odkaz. Aby to vypadalo: nazev kapitoly,
> par tecek a barevne cislo stranky. 

Parametr na to není, takže je potřeba upravit přímo šablony. Stačí do 
stylu s úpravami přidat následující šablonu a odkazy z obsahu budou modré:

<xsl:template name="toc.line">
   <xsl:variable name="id">
     <xsl:call-template name="object.id"/>
   </xsl:variable>

   <xsl:variable name="label">
     <xsl:apply-templates select="." mode="label.markup"/>
   </xsl:variable>

   <fo:block text-align-last="justify"
             text-align="start"
             end-indent="{$toc.indent.width}pt"
             last-line-end-indent="-{$toc.indent.width}pt">
     <fo:inline keep-with-next.within-line="always">
       <fo:basic-link internal-destination="{$id}">
         <xsl:if test="$label != ''">
           <xsl:copy-of select="$label"/>
           <xsl:value-of select="$autotoc.label.separator"/>
         </xsl:if>
         <xsl:apply-templates select="." mode="titleabbrev.markup"/>
       </fo:basic-link>
     </fo:inline>
     <fo:inline keep-together.within-line="always">
       <xsl:text> </xsl:text>
       <fo:leader leader-pattern="dots"
                  leader-pattern-width="3pt"
                  leader-alignment="reference-area"
                  keep-with-next.within-line="always"/>
       <xsl:text> </xsl:text>
       <fo:basic-link internal-destination="{$id}">
         <fo:page-number-citation color="blue" ref-id="{$id}"/>
       </fo:basic-link>
     </fo:inline>
   </fo:block>
</xsl:template>

Nicméně obecně nepovažuji obarvování čísel stran v PDF za dobrý nápad, 
protože většina lidí tiskne černobíle, barva se převede na rast a bude 
špatně čitelná. Pro on-line zobrazení je lepší HTML než PDF a z DocBooku 
dostanete oba formáty zcela automaticky.

-- 
------------------------------------------------------------------
   Jirka Kosek     e-mail: jirka na kosek.cz     http://www.kosek.cz
------------------------------------------------------------------
   Profesionální školení a poradenství v oblasti technologií XML.
      Podívejte se na náš nově spuštěný web http://DocBook.cz
        Podrobný přehled školení http://xmlguru.cz/skoleni/
------------------------------------------------------------------

------------- další část ---------------
A non-text attachment was scrubbed...
Name: smime.p7s
Type: application/x-pkcs7-signature
Size: 3158 bytes
Desc: S/MIME Cryptographic Signature
URL: <http://www.linux.cz/pipermail/docbook/attachments/20050421/10e5ef13/attachment.bin>