XSLT - transformace obrazku do PDF
_zc na centrum.cz
_zc na centrum.cz
Středa Prosinec 12 09:37:57 CET 2007
Řešil jsem podobný problém, nakonec jsem si upravil šablonu "process.image"
tak, aby velké obrázky nepřetékaly. V dokumentaci vkládám obrázky bez udání
rozměrů:
<figure>
<title>Titulek obrazku</title>
<mediaobject>
<imageobject>
<imagedata fileref="obrazek.png" />
</imageobject>
</mediaobject>
</figure>
U inline vkládaných obrázků je ovšem nutno nastavit rozměry, jinak to rozhodí text
kolem nich. Upravená šablona vypadá takto:
<!--
uprava rozmeru obrazku, pokud nejsou zadane zadne rozmery, aby
nepretekal mimo stranku, je pouzito toto:
scalefit="1", width="100%", contentheight="100%"
jako defaultni hodnoty, pokud nejsou zadane
-->
<xsl:template name="process.image">
<!-- When this template is called, the current node should be -->
<!-- a graphic, inlinegraphic, imagedata, or videodata. All -->
<!-- those elements have the same set of attributes, so we can -->
<!-- handle them all in one place. -->
<xsl:variable name="scalefit">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">0</xsl:when>
<xsl:when test="@contentwidth">0</xsl:when>
<xsl:when test="@contentdepth and
@contentdepth != '100%'">0</xsl:when>
<xsl:when test="@scale">0</xsl:when>
<xsl:when test="@scalefit"><xsl:value-of select="@scalefit"/></xsl:when>
<xsl:when test="@width or @depth">1</xsl:when>
<xsl:otherwise>1</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="scale">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">0</xsl:when>
<xsl:when test="@contentwidth or @contentdepth">1.0</xsl:when>
<xsl:when test="@scale">
<xsl:value-of select="@scale div 100.0"/>
</xsl:when>
<xsl:otherwise>1.0</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="filename">
<xsl:choose>
<xsl:when test="local-name(.) = 'graphic'
or local-name(.) = 'inlinegraphic'">
<!-- handle legacy graphic and inlinegraphic by new template -->
<xsl:call-template name="mediaobject.filename">
<xsl:with-param name="object" select="."/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<!-- imagedata, videodata, audiodata -->
<xsl:call-template name="mediaobject.filename">
<xsl:with-param name="object" select=".."/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="content-type">
<xsl:if test="@format">
<xsl:call-template name="graphic.format.content-type">
<xsl:with-param name="format" select="@format"/>
</xsl:call-template>
</xsl:if>
</xsl:variable>
<xsl:variable name="bgcolor">
<xsl:call-template name="dbfo-attribute">
<xsl:with-param name="pis"
select="../processing-instruction('dbfo')"/>
<xsl:with-param name="attribute" select="'background-color'"/>
</xsl:call-template>
</xsl:variable>
<fo:external-graphic>
<xsl:attribute name="src">
<xsl:call-template name="fo-external-image">
<xsl:with-param name="filename">
<xsl:if test="$img.src.path != '' and
not(starts-with($filename, '/')) and
not(contains($filename, '://'))">
<xsl:value-of select="$img.src.path"/>
</xsl:if>
<xsl:value-of select="$filename"/>
</xsl:with-param>
</xsl:call-template>
</xsl:attribute>
<xsl:attribute name="width">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">auto</xsl:when>
<xsl:when test="contains(@width,'%')">
<xsl:value-of select="@width"/>
</xsl:when>
<xsl:when test="@width">
<xsl:call-template name="length-spec">
<xsl:with-param name="length" select="@width"/>
<xsl:with-param name="default.units" select="'px'"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="not(@depth) and $default.image.width != ''">
<xsl:call-template name="length-spec">
<xsl:with-param name="length" select="$default.image.width"/>
<xsl:with-param name="default.units" select="'px'"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>100%</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:attribute name="height">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">auto</xsl:when>
<xsl:when test="contains(@depth,'%')">
<xsl:value-of select="@depth"/>
</xsl:when>
<xsl:when test="@depth">
<xsl:call-template name="length-spec">
<xsl:with-param name="length" select="@depth"/>
<xsl:with-param name="default.units" select="'px'"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>auto</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:attribute name="content-width">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">auto</xsl:when>
<xsl:when test="contains(@contentwidth,'%')">
<xsl:value-of select="@contentwidth"/>
</xsl:when>
<xsl:when test="@contentwidth">
<xsl:call-template name="length-spec">
<xsl:with-param name="length" select="@contentwidth"/>
<xsl:with-param name="default.units" select="'px'"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="number($scale) != 1.0">
<xsl:value-of select="$scale * 100"/>
<xsl:text>%</xsl:text>
</xsl:when>
<xsl:when test="$scalefit = 1">scale-to-fit</xsl:when>
<xsl:otherwise>14cm</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:attribute name="content-height">
<xsl:choose>
<xsl:when test="$ignore.image.scaling != 0">auto</xsl:when>
<xsl:when test="contains(@contentdepth,'%')">
<xsl:value-of select="@contentdepth"/>
</xsl:when>
<xsl:when test="@contentdepth">
<xsl:call-template name="length-spec">
<xsl:with-param name="length" select="@contentdepth"/>
<xsl:with-param name="default.units" select="'px'"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="number($scale) != 1.0">
<xsl:value-of select="$scale * 100"/>
<xsl:text>%</xsl:text>
</xsl:when>
<xsl:when test="$scalefit = 1">scale-to-fit</xsl:when>
<xsl:otherwise>100%</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:if test="$content-type != ''">
<xsl:attribute name="content-type">
<xsl:value-of select="concat('content-type:',$content-type)"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="$bgcolor != ''">
<xsl:attribute name="background-color">
<xsl:value-of select="$bgcolor"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@align">
<xsl:attribute name="text-align">
<xsl:value-of select="@align"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@valign">
<xsl:attribute name="display-align">
<xsl:choose>
<xsl:when test="@valign = 'top'">before</xsl:when>
<xsl:when test="@valign = 'middle'">center</xsl:when>
<xsl:when test="@valign = 'bottom'">after</xsl:when>
<xsl:otherwise>auto</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
</xsl:if>
</fo:external-graphic>
</xsl:template>
<!-- konec upravy rozmeru obrazku -->
Zdeněk
______________________________________________________________
> Od: Hellbard na seznam.cz
> Komu: Diskuse o dokumentaÄnĂm systemu DocBook<docbook na linux.cz>
> Datum: 11.12.2007 07:26
> Předmět: XSLT - transformace obrazku do PDF
>
>Dobrý den, potřeboval bych poradit ohledně transformování docbook
dokumentu do PDF. Mám několika stránkovou dokumentaci, která obsahuje
různě velké obrázky. Při použití standartních xslt šablon mi některé z
obrzků přesáhnou okraj stránky. Hledal jsem proto na webu návody, jak
upravit XSLT šablony, aby obrázky nepřesáhli velikost stránky. To se mi
povedlo ovšem zároveň s tím se mi jiné "malé" obrázky rozthly do obludných
rozměrů. Proto jsem si našel jiné návody, jak obrázkům zachovat jejich
původní velikost. To ovšem vyústilo zase v problém číslo jedna. Moje
skromné schopnosti v XSLT nedokázaly odhalit způsob, jak zajistit obě dvě
varianty, tedy aby se velké obrázky změnšily na rozměr stránky a naopak
malé si zachovaly svoji původní velikost. Prosím pokud jste se již s tímto
problémem někde setkali, budu vděčný za jakoukoli radu
>
>Milan
>_______________________________________________
>Docbook mailing list
>Docbook na linux.cz
>http://www.linux.cz/mailman/listinfo/docbook
>
Další informace o konferenci Docbook